Basilisk - Install silent switches Topic is solved

[ggbce]

Hi,

We have introduced the use of Basilisk browser in our computers. I would like to easly install this application on our computers "silently"... But I'm surprized to don't find anything about that on the official Website, GitHub or on this forum.

Please let me known all "switches" available to install "Basilisk Wb Broswer" Windows package. May be, I could guess something like "/quiet, /q, -quiet, -q, /silent, /s, -s, etc." for silent... But it could also exist many other important switches not documented... like something to no try to force OR try to force the installer to set the browser as the default browser, etc. A complete guide of all install switches will be very appreciated !

Regards,

GGBce

[New Tobin Paradigm]

I don't believe the nsis installer has a silent installer switch because it had to elevate to install system wide. That said, you could likely create something for internal deployment using the 7zip archive to do it and invoke the shell service helper as an administrator to set file associations system wide.

Though, I bet what you are looking for is along the lines of an msi installer which WOULD have those sorts of deployment features. But we don't currently offer that at this time.

[ggbce]

Not really searching for MSI version. NSIS Installer package (and other installers) normally support some basic switches. I just would like to have an official information from the Basilisk dev teams to ensure to get maximal potential of this installation that I could.

Run in elevating mode not change the switches values or installation mode, juste the privileges actions that you can run on a computer. I'm always installing Basilisk setup with an admin account to ensure is installed in "machine-wide" for all users (Installed in C:\Program Files\ and Desktop Shortcut in Public Desktop). Now, I would like to to that silently... for ensure uniform installation (if installed manually), to add installer package in my PDQ Deploy or SCCM or MDT mechanism... Without silent it's not possible to deploy.

[New Tobin Paradigm]

Did a little bit of digging and apparently we DO have a /S switch for silent install.. However, if UAC is enabled it will still ask for elevation. You will need to find a way to deploy with something that can deal with the UAC elevation. I am sure there are various ways to do that.

I haven't tested all of this but I bet it is pretty close and largely applicable cause NSIS is NSIS. https://firefox-source-docs.mozilla.org/browser/installer/windows/installer/FullConfig.html

[ggbce]

Hi,

I will try the "/S". I'm sure this will work if you found it in documentation !!!

For asking or not asking "elevation" prompt... It's not a problem for me.

When I use MDT/SCCM this part is already handle.

When I create my "AUTO-INSTALL" package, I always use the same method for all my packages. I created my own BatchFile (.bat/.cmd) where I validate if the script is started with elevation or not. For all people interested, take a look. I share the information for you :

Code: Select all

@ECHO OFF
ECHO Validation if running on Windows XP or Windows Server 2003... (for old PC)
FOR /f "tokens=3" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"  /v CurrentVersion  ^|findstr /ri "REG_SZ"') do set winversion=%%a
ECHO.
IF /I "%winversion%"=="5.1" (
ECHO Windows XP found...
GOTO NoCheckAdminLevel
) ELSE IF /I "%winversion%"=="5.2" (
ECHO Windows Server 20003 found...
GOTO NoCheckAdminLevel
) ELSE (
ECHO Newer system found. Version: %winversion%
GOTO CheckAdminLevel
)

:CheckAdminLevel

ECHO Validation if elevated privileges is used...
ECHO.

whoami /groups | find "S-1-16-12288" > nul
IF ERRORLEVEL 1 GOTO NotAdmin
IF ERRORLEVEL 0 GOTO ImAdmin

:NotAdmin
CLS
ECHO You didn't launch the script with elevated privileges 
ECHO Script stopped...
ECHO.
PAUSE
EXIT /b 1

:ImAdmin
ECHO Elevated privileges are in force !
ECHO.
ECHO Enable extensions...
@SETLOCAL enableextensions
@CD /d "%~dp0"
ECHO.
GOTO CheckNetworkAccess

:NoCheckAdminLevel
:CheckNetworkAccess
ECHO Check if network share access is available for elevated account via "Current Directory" variable...
ECHO.
ECHO Location: %CD%
IF "%CD%"=="%windir%\system32" GOTO HELP_NET
ECHO.
GOTO CPUCHECK

:HELP_NET
ECHO.
ECHO ###############################################################
ECHO # IMPORTANT:                                                  
ECHO #                                                             
ECHO # This script cannot be runned from a network path because:
ECHO # 
ECHO # A- You have stard it from an UNC instead a mapped drive
ECHO #                                                            
ECHO # B- Your account didn't have proper coniguration to access this path
ECHO # 
ECHO # Option: You can to copy the source files on your C: drive, then try 
ECHO # from this location.
ECHO #
ECHO ###############################################################
ECHO.
PAUSE
EXIT /b 1

:CPUCHECK
ECHO Test OS platform 32 bit or 64 bit...
ECHO.
IF %PROCESSOR_ARCHITECTURE%==AMD64 GOTO SYS64BIT
IF %PROCESSOR_ARCHITECTURE%==x86 GOTO SYS32BIT
CLS
ECHO ERROR: Unable to determine OS platform (32 ou 64 bit)
PAUSE
EXIT /b 1

:SYS64BIT
ECHO 64-bit Operating System detected...
ECHO.
ECHO Installation of Basilisk Web browser (x64) is in progress...
"%CD%\basilisk.win64.installer.exe" /S
GOTO x86_x64

:SYS32BIT
ECHO 32-bit Operating System detected...
ECHO.
ECHO Installation of Basilisk Web browser (x86) is in progress...
"%CD%\basilisk.win32.installer.exe" /S
GOTO x86_x64

:x86_x64
ECHO.
ECHO Common configuration for all platforms...
ECHO.

GOTO END

:END
ECHO Installation completed !
TIMEOUT /T 10

[New Tobin Paradigm]

I think it is case-sensitive so /S not /s.

[ggbce]

NSIS documentation tell we need to use capital "/S" like you said. But I tested "/s" and it work !

I edited my post to ensure better result with "/S"